ledRunningLight 1, 5, color_green, 200


! evtl. altes Log loeschen
f = "LOG.TXT"
if fsFileExists(0,f)
  fsRemove 0, f
endif  


! Spannung pruefen, z.B. nur ein Bereich zwischen
! 3,0 V und 5,0 V ist zulaessig
v = getTargetVoltage()
if (v < 3000) or (v > 5000)
  print "voltage [mV]: ", v, "\r\n"
  throw userException + 1
endif  


! Programmiermode setzen
programTarget


! Signature pruefen, z.B. ATmega32
if getSignature() <> sig_atmega32
  print "wrong controller", "\r\n"
  throw userException + 2
endif  


! Quarz starten, danach Target neu starten
writeBits fuses_low, $fd
writeBits fuses_high, $d9
restartTarget


! Programmiergeschwindigkeit setzen,
! Target loeschen, flashen und starten
setProgrammingSpeed 125
eraseFlash
writeVerifyFileToFlash 0, "DEMO.HEX"                
runTarget


! Nach Exception schauen und ins Log schreiben
catch exception
if exception <> 0
  print "exception: ", exception
else  
  print "successfully flashed"
  ledOn 5, color_green
endif


! Nachdem die Exception mittels catch gefangen wurde,
! erneut setzen. Damit wird die Nummer der Exception
! ueber die LEDs durch Blinkcode angezeigt. 
throw exception